On Wilson's "On Hsu's Suggestivity and Idioms"

Recently, Brandon Wilson posted a nice article discussing a nice article discussing a way in which APL's algebraic properties absolutely shine.

A table is presented in the article, where the sixteen — or twelve⁽¹⁾ — Boolean functions are mixed with the four functions 0∘⍪, 1∘⍪, ⍪∘0 and ⍪∘1 and used in a pairwise reduction, which has the effect of identifying certain properties of groups in a Boolean vector. Some of the entries, however, appear quite redundant after considering the relations that the sixteen Boolean functions have between each other.

Here are the entries from the article's table which I consider important, with descriptions changed to be more —er— descriptive, formatted as a Dyalog session.

      _F_←{2⍵⍵⌿⍺⍺ ⍵}
      ⊢Y←(0 1 1 1 0 0 0 0)(0 1 1 1 0 0 0 1)(1 1 1 1 0 0 0 0)(1 1 1 1 0 0 0 1)
0 1 1 1 0 0 0 0  0 1 1 1 0 0 0 1  1 1 1 1 0 0 0 0  1 1 1 1 0 0 0 1 
      0∘⍪_F_<¨Y ⍝ head of 1-groups
0 1 0 0 0 0 0 0  0 1 0 0 0 0 0 1  1 0 0 0 0 0 0 0  1 0 0 0 0 0 0 1 
      1∘⍪_F_<¨Y ⍝ head of 1-groups, except at start
0 1 0 0 0 0 0 0  0 1 0 0 0 0 0 1  0 0 0 0 0 0 0 0  0 0 0 0 0 0 0 1 
      ⍪∘1_F_>¨Y ⍝ last of 1-groups
0 0 0 1 0 0 0 0  0 0 0 1 0 0 0 0  0 0 0 1 0 0 0 0  0 0 0 1 0 0 0 0 
      ⍪∘0_F_>¨Y ⍝ last of 1-groups, except at end
0 0 0 1 0 0 0 0  0 0 0 1 0 0 0 1  0 0 0 1 0 0 0 0  0 0 0 1 0 0 0 1 
      0∘⍪_F_∧¨Y ⍝ tail of 1-groups
0 0 1 1 0 0 0 0  0 0 1 1 0 0 0 0  0 1 1 1 0 0 0 0  0 1 1 1 0 0 0 0 
      1∘⍪_F_∧¨Y ⍝ tail of 1-groups, including start
0 0 1 1 0 0 0 0  0 0 1 1 0 0 0 0  1 1 1 1 0 0 0 0  1 1 1 1 0 0 0 0 
      ⍪∘0_F_∧¨Y ⍝ init of 1-groups
0 1 1 0 0 0 0 0  0 1 1 0 0 0 0 0  1 1 1 0 0 0 0 0  1 1 1 0 0 0 0 0 
      ⍪∘1_F_∧¨Y ⍝ init of 1-groups, including end
0 1 1 0 0 0 0 0  0 1 1 0 0 0 0 1  1 1 1 0 0 0 0 0  1 1 1 0 0 0 0 1

      1∘⍪_F_>¨Y ⍝ head of 0-groups
1 0 0 0 1 0 0 0  1 0 0 0 1 0 0 0  0 0 0 0 1 0 0 0  0 0 0 0 1 0 0 0 
      0∘⍪_F_>¨Y ⍝ head of 0-groups, except at start
0 0 0 0 1 0 0 0  0 0 0 0 1 0 0 0  0 0 0 0 1 0 0 0  0 0 0 0 1 0 0 0 
      ⍪∘1_F_<¨Y ⍝ last of 0-groups
1 0 0 0 0 0 0 1  1 0 0 0 0 0 1 0  0 0 0 0 0 0 0 1  0 0 0 0 0 0 1 0 
      ⍪∘0_F_<¨Y ⍝ last of 0-groups, except at end
1 0 0 0 0 0 0 0  1 0 0 0 0 0 1 0  0 0 0 0 0 0 0 0  0 0 0 0 0 0 1 0 
      1∘⍪_F_⍱¨Y ⍝ tail of 0-groups
0 0 0 0 0 1 1 1  0 0 0 0 0 1 1 0  0 0 0 0 0 1 1 1  0 0 0 0 0 1 1 0 
      0∘⍪_F_⍱¨Y ⍝ tail of 0-groups, including start
1 0 0 0 0 1 1 1  1 0 0 0 0 1 1 0  0 0 0 0 0 1 1 1  0 0 0 0 0 1 1 0 
      ⍪∘1_F_⍱¨Y ⍝ init of 0-groups
0 0 0 0 1 1 1 0  0 0 0 0 1 1 0 0  0 0 0 0 1 1 1 0  0 0 0 0 1 1 0 0 
      ⍪∘0_F_⍱¨Y ⍝ init of 0-groups, including end
0 0 0 0 1 1 1 1  0 0 0 0 1 1 0 0  0 0 0 0 1 1 1 1  0 0 0 0 1 1 0 0

      0∘⍪_F_≠¨Y ⍝ head of groups [a]
0 1 0 0 1 0 0 0  0 1 0 0 1 0 0 1  1 0 0 0 1 0 0 0  1 0 0 0 1 0 0 1 
      1∘⍪_F_≠¨Y ⍝ head of groups [b]
1 1 0 0 1 0 0 0  1 1 0 0 1 0 0 1  0 0 0 0 1 0 0 0  0 0 0 0 1 0 0 1 
      ⍪∘0_F_≠¨Y ⍝ last of groups [a]
1 0 0 1 0 0 0 0  1 0 0 1 0 0 1 1  0 0 0 1 0 0 0 0  0 0 0 1 0 0 1 1 
      ⍪∘1_F_≠¨Y ⍝ last of groups [b]
1 0 0 1 0 0 0 1  1 0 0 1 0 0 1 0  0 0 0 1 0 0 0 1  0 0 0 1 0 0 1 0 
      1∘⍪_F_=¨Y ⍝ tail of groups [a]
0 0 1 1 0 1 1 1  0 0 1 1 0 1 1 0  1 1 1 1 0 1 1 1  1 1 1 1 0 1 1 0 
      0∘⍪_F_=¨Y ⍝ tail of groups [b]
1 0 1 1 0 1 1 1  1 0 1 1 0 1 1 0  0 1 1 1 0 1 1 1  0 1 1 1 0 1 1 0 
      ⍪∘1_F_=¨Y ⍝ init of groups [a]
0 1 1 0 1 1 1 0  0 1 1 0 1 1 0 1  1 1 1 0 1 1 1 0  1 1 1 0 1 1 0 1 
      ⍪∘0_F_=¨Y ⍝ init of groups [b]
0 1 1 0 1 1 1 1  0 1 1 0 1 1 0 0  1 1 1 0 1 1 1 1  1 1 1 0 1 1 0 0 

      ⍪∘0_F_⊢¨Y ⍝ shift left, insert 0
1 1 1 0 0 0 0 0  1 1 1 0 0 0 1 0  1 1 1 0 0 0 0 0  1 1 1 0 0 0 1 0 
      ⍪∘1_F_⊢¨Y ⍝ shift left, insert 1
1 1 1 0 0 0 0 1  1 1 1 0 0 0 1 1  1 1 1 0 0 0 0 1  1 1 1 0 0 0 1 1 
      0∘⍪_F_⊣¨Y ⍝ shift right, insert 0
0 0 1 1 1 0 0 0  0 0 1 1 1 0 0 0  0 1 1 1 1 0 0 0  0 1 1 1 1 0 0 0 
      1∘⍪_F_⊣¨Y ⍝ shift right, insert 1
1 0 1 1 1 0 0 0  1 0 1 1 1 0 0 0  1 1 1 1 1 0 0 0  1 1 1 1 1 0 0 0

"Head", "last", "tail" and "init" are used here to mean the first, last, all but first and all but last elements of a group respectively. [a] and [b] respectively indicate that the functions ignore either 0s or 1s at the beginning/end (as appropriate) of the sequence.

The sixteen Boolean that I have been talking about are these (left argument first column, right argument first row)

0: `0⍨`	0	1
0	0	0
1	0	0

1: `∧`	0	1
0	0	0
1	0	1

2: `>`	0	1
0	0	0
1	1	0

3: `⊣`	0	1
0	0	0
1	1	1

4: `<`	0	1
0	0	1
1	0	0

5: `⊢`	0	1
0	0	1
1	0	1

6: `≠`	0	1
0	0	1
1	1	0

7: `∨`	0	1
0	0	1
1	1	1

8: `⍱`	0	1
0	1	0
1	0	0

9: `=`	0	1
0	1	0
1	0	1

10: `~⊢`	0	1
0	1	0
1	1	0

11: `≥`	0	1
0	1	0
1	1	1

12: `~⊣`	0	1
0	1	1
1	0	0

13: `≤`	0	1
0	1	1
1	0	1

14: `⍲`	0	1
0	1	1
1	1	0

15: `1⍨`	0	1
0	1	1
1	1	1

The entries are suggestively numbered according to the base-2 decode of the ravel of the 2x2 result matrix.

Some of these functions have matching operators in TMN⁽²⁾. Obviously there's $\land$ (∧) and $\lor$ (∨), and the complementary (with symbols somewhat uncommon in TMN) $\overline\land$ or $\uparrow$ (⍲) and $\overline\lor$ or $\downarrow$ (⍱), then there is $\veebar$ or $\oplus$ (≠ acting as an exclusive or) and the opposite $\Leftrightarrow$ or $\leftrightarrow$ (= acting as the biconditional), but also $\Rightarrow$ or $\rightarrow$ (≤, which is equivalent to logical implication).

Because of the nature of Booleans, each of these functions can be constructed by negating another (specifically, the negated N-th function is the same as the (15 - N)-th function). This means that, for example, 2∘(>⌿)1∘⍪, the function that finds the heads of 0-groups, negates to 2∘(≤⌿)0∘⍪, what Wilson calls "not 0-group head". This allows for a great simplification of the big table that appears in the article, equipped with the knowledge of the sixteen Boolean functions and their relations.

Of course, there are many more relations to be found. The possibility of negating each of the two arguments, as well as the result, gives 7 different relation types, ignoring the identity, of which today I only considered one. Finding the numerical relation is trivial, but linking it back to the group-identifying algorithms we have been considering throughout the article may not be. Other possibilities might involve combining both two Boolean functions and their result on groups with a third function.

Wilson excludes the two constant functions and the two negated identities up until the very end of the article.
Traditional math notation, that is, the syntax generally used in mathematics.

On Wilson's "On Hsu's Suggestivity and Idioms"

Footnotes